Here is something to get you started.
Firstly let's make a simple SPICE model for a single solar cell. We have a current source in parallel with a diode, we also have a voltage source which we will sweep to calculate the IV curve.
Here is the spice model,
* Single solar cell solar cell
Isc1 0 1 390.30
d1 1 0 GaAs_diode
vs 1 2 0
vcc 2 0 0.7
* Ideal GaAs diode
.model GaAs_diode d (is=1.1955e-17 n=1 eg=1.42 vj=0.0 jsw=0.0 ik=0.0 ikr=0.0 rs=0.0 fc=0.0 fcs=0.0 M=0.0 MJSW=0.0)
* Perform DC sweep
.dc vcc 0.0V 1.17V 0.0001V
* Export the data from the sweep
.control
set filetype=ascii
run
plot i(vs)*v(2) i(vs)
write output.txt i(vs)
.endc
Here is the current voltage curve (green, labelled i(vs)
) and power voltage curve (red, labelled i(vs)v(2)
).
Now put three of these in series and have all being illuminated,
* 3 solar cells
Isc1 0 1 390.30
d1 1 0 GaAs_diode
Isc2 1 2 379.83
d2 2 1 GaAs_diode
Isc3 2 3 379.83
d3 3 2 GaAs_diode
vs 3 4 0
vcc 4 0 1.3
* Ideal GaAs diode
.model GaAs_diode d (is=1.1955e-17 n=1 eg=1.42 vj=0.0 jsw=0.0 ik=0.0 ikr=0.0 rs=0.0 fc=0.0 fcs=0.0 M=0.0 MJSW=0.0)
* Perform DC sweep
.dc vcc 0.0V 3.5V 0.001V
* Export the data from the sweep
.control
set filetype=ascii
run
plot i(vs)*v(4) i(vs)
write output.txt i(vs)
.endc
You can see that the current is identical but the voltage has added. This is exactly what we expect from putting current sources in series (i.e. the same would happen if you put three batteries in series).
OK now let's shade the first and the last solar cell so the short-circuit current each generates is 100 A/m$^2$
* 3 solar cells with shading
Isc1 0 1 100.30
d1 1 0 GaAs_diode
Isc2 1 2 379.83
d2 2 1 GaAs_diode
Isc3 2 3 100.83
d3 3 2 GaAs_diode
vs 3 4 0
vcc 4 0 1.3
* Ideal GaAs diode
.model GaAs_diode d (is=1.1955e-17 n=1 eg=1.42 vj=0.0 jsw=0.0 ik=0.0 ikr=0.0 rs=0.0 fc=0.0 fcs=0.0 M=0.0 MJSW=0.0)
.options rshunt = 1e12
* Perform DC sweep
.dc vcc 0.0V 3.5V 0.001V
* Export the data from the sweep
.control
set filetype=ascii
run
plot i(vs)
write output.txt i(vs)
.endc
Just plotting the current let's compare to the previous case. You can see that the current passing through the series connected cells is equal to the lowest current generated by the lowest current producing diode (100 A/m$^2$).
This is called the current matching constraint. For maximum efficiency all series connected diodes must generated the same current.
So if the adjacent cells contribute less and less current, eventually no current will flow (or very little depending on the shunt resistance).
If you remove the adjacent cells, there is no current matching condition and you return to a single solar cell IV curve.