2
$\begingroup$

When you connect, let's say, three photodiodes or solar cells, with a load, and you measure the voltage across the middle photodiode. Will the voltage change if

  1. the adjacent cells are in the dark
  2. if they wouldn't be there at all? (and how would it change?)

Would there be no bias at all?

Improve this question
$\endgroup$

1 Answer 1

Reset to default
4
$\begingroup$

Here is something to get you started.

Firstly let's make a simple SPICE model for a single solar cell. We have a current source in parallel with a diode, we also have a voltage source which we will sweep to calculate the IV curve.

solar cell spice model with sweep bias voltage

Here is the spice model,

* Single solar cell solar cell

Isc1 0 1 390.30
d1 1 0 GaAs_diode

vs 1 2 0

vcc 2 0 0.7

* Ideal GaAs diode
.model GaAs_diode d (is=1.1955e-17 n=1 eg=1.42 vj=0.0 jsw=0.0 ik=0.0 ikr=0.0 rs=0.0 fc=0.0 fcs=0.0 M=0.0 MJSW=0.0) 

* Perform DC sweep
.dc vcc 0.0V 1.17V 0.0001V

* Export the data from the sweep
.control 
set filetype=ascii
run 
plot i(vs)*v(2) i(vs)
write output.txt i(vs)
.endc

Here is the current voltage curve (green, labelled i(vs)) and power voltage curve (red, labelled i(vs)v(2)).

IV curve single solar cell

Now put three of these in series and have all being illuminated,

* 3 solar cells

Isc1 0 1 390.30
d1 1 0 GaAs_diode

Isc2 1 2 379.83
d2 2 1 GaAs_diode

Isc3 2 3 379.83
d3 3 2 GaAs_diode

vs 3 4 0

vcc 4 0 1.3

* Ideal GaAs diode
.model GaAs_diode d (is=1.1955e-17 n=1 eg=1.42 vj=0.0 jsw=0.0 ik=0.0 ikr=0.0 rs=0.0 fc=0.0 fcs=0.0 M=0.0 MJSW=0.0) 

* Perform DC sweep
.dc vcc 0.0V 3.5V 0.001V

* Export the data from the sweep
.control 
set filetype=ascii
run 
plot i(vs)*v(4) i(vs)
write output.txt i(vs)
.endc

3 solar cells in series

You can see that the current is identical but the voltage has added. This is exactly what we expect from putting current sources in series (i.e. the same would happen if you put three batteries in series).

OK now let's shade the first and the last solar cell so the short-circuit current each generates is 100 A/m$^2$

* 3 solar cells with shading

Isc1 0 1 100.30
d1 1 0 GaAs_diode

Isc2 1 2 379.83
d2 2 1 GaAs_diode

Isc3 2 3 100.83
d3 3 2 GaAs_diode

vs 3 4 0

vcc 4 0 1.3

* Ideal GaAs diode
.model GaAs_diode d (is=1.1955e-17 n=1 eg=1.42 vj=0.0 jsw=0.0 ik=0.0 ikr=0.0 rs=0.0 fc=0.0 fcs=0.0 M=0.0 MJSW=0.0) 

.options rshunt = 1e12

* Perform DC sweep
.dc vcc 0.0V 3.5V 0.001V

* Export the data from the sweep
.control 
set filetype=ascii
run 
plot i(vs)
write output.txt i(vs)
.endc

Just plotting the current let's compare to the previous case. You can see that the current passing through the series connected cells is equal to the lowest current generated by the lowest current producing diode (100 A/m$^2$).

This is called the current matching constraint. For maximum efficiency all series connected diodes must generated the same current.

3 cells with shading

So if the adjacent cells contribute less and less current, eventually no current will flow (or very little depending on the shunt resistance).

If you remove the adjacent cells, there is no current matching condition and you return to a single solar cell IV curve.

Improve this answer
$\endgroup$
7
  • $\begingroup$ Thanks for your effort in modeling the problem! I try to understand your answer step by step. One thing I wonder: Why, when I search for "current matching constraint", do I only find papers related on tandem solar cells? $\endgroup$
    – AskingBecauseIHaveQuestions
    Commented Oct 26, 2020 at 20:30
  • $\begingroup$ Probably because it's a term used in solar literature. But it's just based on Kirchoff's law en.wikipedia.org/wiki/Kirchhoff%27s_circuit_laws $\endgroup$
    – boyfarrell
    Commented Oct 26, 2020 at 20:41
  • $\begingroup$ The Kirchhoff law is about currents entering and leaving a node, not about currents in series. Or do you mean that this can be derived from the law that voltages in a loop add up to zero? $\endgroup$
    – AskingBecauseIHaveQuestions
    Commented Oct 26, 2020 at 21:39
  • $\begingroup$ I mean that charge cannot accumulate so current flowing through all solar cells must be the same. $\endgroup$
    – boyfarrell
    Commented Oct 26, 2020 at 21:51
  • $\begingroup$ Ah, okay, I understand what you mean! I guess that also follows from the Kirchhoff laws (although referring to continuity equation would have been more clear to me). So one shaded cell will "slow down" all others? That is really interesting!! I never thought about it this way!! My next question (in case I understood you correctly so far): You demonstrated that the voltage has been "added". So does this mean that illuminated adjacent cells forward bias each other? Is there a second way to explain this (different from pointing to general expectations about voltages in series circuits)? $\endgroup$
    – AskingBecauseIHaveQuestions
    Commented Oct 26, 2020 at 21:53

Not the answer you're looking for? Browse other questions tagged or ask your own question.