Prefix all lines with the first word in a file

Question

I want to prefix all the lines of a file (except first line) using the first word in a file.

Input:

x.o: x.cpp /u/a.h 
/b.h \
/c.h \

output:

x.o: x.cpp /u/a.h \
x.o: /b.h \
x.o: /c.h \

Can anyone please help me how to solve the above using sed?

Answer 1

You can do it like this with GNU sed:

sed -r '1 {h; s/ .*//; x}; 1!{G; s/([^\n]*)\n(.*)/\2 \1/}' infile

Or as a separate script:

parse.sed

1 {                         # run block for first line only
  h                         # save copy of line in hold space
  s/ .*//                   # remove redundant part
  x                         # swap prefix to hold space
}

1! {                        # when not first line
  G                         # append prefix to pattern space
  s/([^\n]*)\n(.*)/\2 \1/   # reorganize so prefix is the prefix
}

Run it like this:

 sed -rf parse.sed infile

Output:

x.o: x.cpp /u/a.h 
x.o: /b.h \
x.o: /c.h \

Answer 2

Perl solution:

perl -pe 'print $prefix; ($prefix) = /^(.+? )/ if 1..1' INPUT.TXT