How to find the line with the maximum number of columns/characters in Vim/gVim?

Question

I'm currently using gVim on Windows XP, and I have 2 follow-ups to my core question:

What is the best method of finding the line with the most characters?

My current method: I use the regex search :/^\(\p\)\{#number#,}$), and I keep increasing the integer #number# until I get just one match. In the case of my file, it is a line of only 81K characters - not 916,657 as I previously thought. I know this because when the cursor is on that line I press g + Ctrl+g and get the column count of 81K.

Followup 1) Is the question "What is the best method of finding the line with the most columns?" the same as #2 above?

Followup 2) What does the second number mean when I open a file and see the following line at the bottom of the screen:

I interpret this to mean that the file has 14,871 lines, and at least one row has 916,657 columns. I checked that the file does have 14,871 lines, but I have not been able to understand the purpose of the second (916K).

Answer 1

The second number is the total character count in the whole file. If you do:

$ wc -l -c filename

you should see the same two numbers (lines and total characters). In fact, you can do:

:!wc -l -c %

Here's a plugin called textfilter (download) that includes a function to find the longest line.

Or you can use this to find the length of the longest line:

:echo max(map(range(1, line('$')), "col([v:val, '$'])")) - 1

then you can use that number like this:

/^.\{248\}$

Answer 2

There must be a better way but the following will also do:

%s/./a/g         "Replace everything with 'a's
sort!            "Sort by column length
ggy$             "Go to first line (longest) and copy it
u                "Undo the sorting
/<c-r>"          "Search for the longest line
mm               "Mark it 'm'
u                "Undo the replace
'm               "Go to the mark - there!

Answer 3

Cam't speak to the first question, but that second number in the file load message is the total number of characters in the file.

Answer 4

Here's a function that does that.

function MaxLine()
    let maxcol = 0
    let lnum = 1
    while lnum <= line("$")
        call cursor(lnum, 0)
        if col("$") > maxcol
            let maxcol = col("$")
            let maxline = lnum
        endif
        let lnum += 1
    endwhile
    echo "Line" maxline "has" maxcol - 1 "characters"
endfunction

You can execute it with

:call MaxLine()

or define a command or mapping to call it.

Note that finding the line with the most actual columns is the same as the line with the most characters. That may not be the same as the line with the most bytes. If you want to find the line with the most virtual columns, replace col("$") with virtcol("$").

Answer 5

Not so vim-centric, and similar to some other answers, but maybe more intuitive for some people. This assumes you're ok with calling some external programs from within vim.

I have the following in file test_file:

hello world
helloooooooooooooo world !!!
yo, world!
helloooOoooOooooOo World ! !

The wc command sometimes has an -L option that prints the size of the longest line. 28 test_file is the output for my example.

You could print these 28 character lines (and their line nums) with grep -nP ".{28}" test_file.

2:helloooooooooooooo world !!!
4:helloooOoooOooooOo World ! !

You could parse the wc output with cut. Putting it all together and sticking one command into another, it's:

grep -nP ".{$(wc -L test_file | cut -f 1 -d ' ')}" test_file

Answer 6

For whole file:

max(map(getline(0, "$"), "len(v:val)"))

For selection:

max(map(getline("'<", "'>"), "len(v:val)"))

If you have multi-bytes in the file replace len() with strchars(), strwidth(), strdisplaywidth() or what fit's ones needs.