How can I force zsh to write automatically complete path to history?

Question

Suppose I did some time ago cd /path/to/foo/bar and then evince file.pdf. Now if I want to open file.pdf again I have also to do both steps again (using history). However I would do it in a single step. I.e. I want that not evince file.pdf is written to .zsh_history but evince /path/to/foo/bar/file.pdf. How can I achieve this for example by modifying my .zshrc? evince is only an example. It should work with any command.

Should I have any drawbacks in mind with this new behavior?

N.B: Currently I am using z vor cd history and fzf for general history.

Answer 1

That's not something that could be done for arbitrary shell code as zsh has no way to know which of the words in the code are actually arguments that a command would treat as a file path let alone as a path relative to the current working directory at the time the code is stored onto the history.

For the simplest shell code such as cmd with its literal arguments and for a limited predefined set of commands, you could do something like:

commands_with_expanded_paths=(evince okular)
zshaddhistory() {
  local words=( ${(z)1%$'\n'} )
  if (( $commands_with_expanded_paths[(Ie)$words[1]] )); then
    local replaced_words=($words[1]) word
    for word in $words[2,-1]; do
      local decoded_word=${(Q)word}
      if [[ $decoded_word = [^/]* && -e $decoded_word ]]; then
        word=${(q+)decoded_word:P}
      fi
      replaced_words+=($word)
    done
    print -rs -- $replaced_words
    fc -p
  fi
}

Where if the first word is the name of a command in a given list, the remaining arguments are replaced with their absolute path if they're found to be relative paths to existing files in the text saved onto the history.