Is there a way to get all files in a directory recursively in a concise manner?

Question

I mean usable in one-liners. For example this:

raku -e 'dir(".")==>say()'

prints all files and directories in the current directory. How do I update it so it works recursively (without libraries and/or user-defined routines)? Or is it not possible?

I saw the :recursive flag mentioned somewhere, but that doesn't work:

> raku -e 'dir(".", :recursive)==>say()'
Cannot resolve caller dir(Str:D, :recursive); none of these signatures matches:
    (IO(Any) $path, Mu :$test!)
    (IO(Any) $path)
    (Mu :$test!)
    ()
  in block <unit> at -e line 1

It could be useful in environments with missing shell tools (on Windows) or with different versions/forks of common tools.

Answer 1

Documentation for &?BLOCK actually gives its example for your use case, so here is a way:

for '.' {
    .Str.say when !.IO.d;
    .IO.dir()».&?BLOCK when .IO.d # let's recurse a little! 
}

• it starts from the current directory '.'
• if it's not a directory (!.IO.d), then stringify and print
• else, it's a directory; so get the .dir of that and repeat this procedure recursively (thanks to &?BLOCK) over all contents (thanks to >>) of this directory
  • &?BLOCK refers to what is between the curly brackets (with the topic variable $_)
  • >> (or ») is the hyper method call operator that is essentially giving a map behaviour here (but it has more to in it; you can see the documentation and/or this thread)

This can be rearranged and modified a little to get

!.IO.d ?? .put !! .IO.dir».&?BLOCK for "."

• the 2 when checks are unified into a ternary since they are collectively exhaustive and mutually exclusive
• .Str.say is actually .Str.gist.put but put would be already stringifying and the gist of a string is itself, so .Str.say is reducible to .put
• no need for parantheses after dir to disambiguate it from anything, so we erase that as well
• we switch to the statement modifier version of the for loop since we have a single statement going on
• here no curlies are present but there is still a block attached to the for loop (comprising of that single statement), so &?BLOCK still works

Answer 2

There is no quick solution in Raku core.

There are several solutions in the Raku ecosystem. Personally, I prefer paths. But then I'm the author of that module, and thus biased :-)

EDIT:

$ zef install paths
$ raku -Mpaths -e '.say for paths'

Answer 3

Adapting the answer from the Raku Docs:

~$ raku -e 'my @stack = ".".IO;
            my $all-files = gather while @stack {
              with @stack.pop {
                when :d { @stack.append: .dir };
                .take
              };
            };
            $all-files.join("\n").put;'

Of course, with Raku you don't have to worry about mashing that answer onto one physical line:

~$ raku -e 'my @stack = ".".IO; my $all-files = gather while @stack { with @stack.pop { when :d { @stack.append: .dir }; .take }; }; $all-files.join("\n").put;'

Note, in the one-liner each closing-} curlie is followed by a semicolon. Raku makes them optional if followed immediately by a newline (at least that's how I understand it). See link below.

https://docs.raku.org/language/syntax#Separating_Statements_with_Semicolons