Less verbose debug screen in Catalyst?

Question

in my stage server I would like to activate the debug so the clients can find errors for themselves before the app goes to the production server.

BUT I only want the first part of the message, not the Request, or the Session Data.

For example: Couldn't render template "templates/home.tt2: file error - templates/inc/heater: not found".

The message is enough for me and for my client to see that the "header" call is misspelled.

The Request has a lot of irrelevant information for the client, but also has A LOT of internal developing information that should be hidden all the time!!

Regards

Answer 1

What you want is to override Catalyst's dump_these method. This returns a list of things to display on Catalyst's error debugging page.

The default implementation looks like:

sub dump_these {
    my $c = shift;
    [ Request => $c->req ],
    [ Response => $c->res ],
    [ Stash => $c->stash ],
    [ Config => $c->config ];
}

but you can make it more restrictive, for example

sub dump_these {
    my $c = shift;
    return [ Apology => "We're sorry that you encountered a problem" ],
           [ Response => substr($c->res->body, 0, 512) ];
}

You would define dump_these in your app's main module -- the one where you use Catalyst.

Answer 2

I had a similar problem that I solved by overriding the Catalyst method log_request_parameters.

Something like this (as @mob said, put it in your main module):

sub log_request_parameters {
    my $c          = shift;
    my %all_params = @_; 

    my $copy = Clone::clone(\%all_params);  # don't change the 'real' request params

    # Then, do anything you want to only print what matters to you,
    # for example, to hide some POST parameters:
    my $body = $copy->{body} || {}; 
    foreach my $key (keys %$body) {
        $body->{$key} = '****' if $key =~ /password/;
    }

    return $c->SUPER::log_request_parameters( %$copy );
}

But you could also simply return at the beginning, if you don't want any GET/POST parameters displayed.

Answer 3

Well, I didn't think of the more obvious solution, in your case: you could simply set your log level to something higher than debug, which would prevent these debug logs from being displayed, but would keep the error logs:

    # (or a similar condition to check you are not on the production server)
    if ( !__PACKAGE__->config->{dev} ) {
        __PACKAGE__->log->levels( 'warn', 'error', 'fatal' ) if ref __PACKAGE__->log;
    }