Calculating Modified V5 Dice Probabilities with AnyDice

Question

My game uses 5th edition rules with a house rule where 1s subtract successes and 10s count as two successes. 2s through 5s count as no successes and 6s through 9s count as single successes as normal.

I'd like to compare the specific probability ranges to V5's normal rules. What function can I use to do so over AnyDice?

Answer 1

Here is a short mock up of code to compare the two. wodvfive is the original rules and wodcustom is your new rules.

function: wodvfive roll COUNT:n dice {
  RELABELED: {1, 2:4, 9:4, 10}
  result: [wodvfive roll COUNT d RELABELED]
}

function: wodvfive roll ROLL:s {
  
  SUPERSUCCESSES: [count {10} in ROLL]
  SUCCESSES: [count {9} in ROLL]
  BOTCHES: [count {1} in ROLL]

  if (SUCCESSES+SUPERSUCCESSES = 0) & BOTCHES > 0 {
    result: -1
  }
  else
  {
    result: SUCCESSES+SUPERSUCCESSES+2*(SUPERSUCCESSES/2)
  }

}

function: wodcustom roll COUNT:n dice {
  RELABELED: {1,2:4,9:4,10}
  result: [wodcustom roll COUNT d RELABELED]
}

function: wodcustom roll ROLL:s {
  SUPERSUCCESSES: [count {10} in ROLL]
  SUCCESSES: [count {9} in ROLL]
  BOTCHES: [count {1} in ROLL]

  TOTALSUCCESSES: SUCCESSES+2*SUPERSUCCESSES-BOTCHES

  if TOTALSUCCESSES < 0 {
    if SUCCESSES+SUPERSUCCESSES = 0 {
      result: -1
    }
    else {
      result: 0
    }
  }
  else {
    result: TOTALSUCCESSES
  }
}

output [wodvfive roll 3 dice]
output [wodcustom roll 3 dice]