Including the slide title in the Notes handout automatically (PowerPoint 2016)

Question

I want to create a manual from a PowerPoint presentation, where the information in the Notes section are part of the printout. So that I can format the slide titles to be part of a table of contents, I want the slide title to be in text, not just part of the slide image.

As export options, I can either choose Notes below slides (but the slide title is not in text format), or I can print the Outline only (but the slide notes aren't included.)

In the Notes Master, I see a Header box, and tried to put a slide title there, but there does not seem to be a way to specify the slide title for each slide automatically. that is ,I can't include a variable for the title in the Header box.

If I look in Outline view, I don't see the notes text.

Is there a way to automatically create a handout that includes both the Outline information and the notes text?

Answer 1

This will pick up the each slide's title text and add it to the notes page. Modify as needed to change the text formatting/position.

Sub AddTitlesToNotesPages()

    Dim oSld As Slide
    Dim oShp As Shape
    Dim sTitleText As String

    For Each oSld In ActivePresentation.Slides

        ' get the slide's title text
        sTitleText = GetTitleText(oSld)

        ' add a text shape with the text to notes page
        ' placement is totally arbitrary; edit to suit
        Set oShp = oSld.NotesPage.Shapes.AddTextbox(msoTextOrientationHorizontal, _
                   0, 0, 500, 100)
        With oShp.TextFrame.TextRange
            .Text = sTitleText
            ' modify other stuff as needed
            .Font.Name = "Arial"
            .Font.Color.RGB = RGB(0, 0, 0)  ' black
            ' and so on
        End With
    Next     ' Slide

End Sub

Function GetTitleText(oSld As Slide) As String
' Returns the title text for oSld if any, or "Slide xxx" if not
    Dim oShp As Shape
    Dim sTemp As String
    For Each oShp In oSld.Shapes
        If oShp.Type = msoPlaceholder Then
            If oShp.PlaceholderFormat.Type = ppPlaceholderCenterTitle Or oShp.PlaceholderFormat.Type = ppPlaceholderTitle Then
                sTemp = oShp.TextFrame.TextRange.Text
            End If
        End If
    Next

    ' if we got this far and didn't find a slide title:
    If Len(sTemp) = 0 Then
        ' return the slide index number
        GetTitleText = "Slide " & CStr(oSld.SlideIndex)
    Else
        ' return the title
        GetTitleText = sTemp
    End If

End Function